Jak przetwarzać dane do jednego wyniku w Excelu za pomocą funkcji REDUCE i LAMBDA?

Wprowadzenie

Funkcja REDUCE pozwala przetwarzać wiele elementów danych i sprowadzać je do jednego wyniku końcowego. To właśnie dlatego jej nazwa bardzo dobrze oddaje sens działania: Excel bierze całą tablicę, przechodzi po niej krok po kroku i za każdym razem aktualizuje jeden wspólny rezultat.

Jeżeli SCAN pokazuje wszystkie etapy pośrednie, to REDUCE idzie o krok dalej i zwraca już tylko efekt końcowy. Dzięki temu świetnie nadaje się do zadań, w których nie interesuje Cię cała droga obliczeń, tylko ostateczna odpowiedź.

To podejście jest bardzo zbliżone do programowania funkcyjnego. Excel nie wykonuje tu pojedynczego prostego działania na jednym zakresie, lecz buduje mały mechanizm przetwarzania. Dla każdej kolejnej wartości uruchamia tę samą logikę i aktualizuje akumulator, czyli wynik przechowywany pomiędzy krokami.

Właśnie w tym miejscu pojawia się funkcja LAMBDA. LAMBDA pozwala tworzyć własną logikę działania bez VBA. Możesz w niej zdefiniować nazwy argumentów, opisać zależność między poprzednim wynikiem a nową wartością i zamknąć cały mechanizm w jednej formule.

W praktyce LAMBDA przyjmuje zwykle dwa argumenty robocze: poprzedni wynik i bieżący element. Następnie wykonuje działanie i zwraca nowy wynik. REDUCE powtarza ten proces aż do końca zakresu, ale na końcu pokazuje tylko jedną wartość.

To bardzo ważna różnica względem SCAN. SCAN rozlewa wyniki po kolejnych komórkach, a REDUCE zwraca jedną końcową odpowiedź. Z tego powodu REDUCE nie jest funkcją rozlewającą się w sensie wyniku końcowego, ale nadal pracuje na tablicach i bardzo dobrze wpisuje się w nowoczesny, dynamiczny sposób budowania formuł w Excelu 365.

REDUCE sprawdza się wszędzie tam, gdzie chcesz zredukować wiele danych do jednej odpowiedzi.

Możesz użyć tej funkcji do:

• sumowania wartości z dodatkową logiką,
• mnożenia kolejnych liczb,
• zliczania tylko wybranych elementów,
• liczenia wartości dodatnich albo ujemnych,
• budowania jednego tekstu z wielu komórek,
• tworzenia własnych reguł agregacji,
• przetwarzania słów w zdaniu,
• składania danych tekstowych i liczbowych w jeden wynik,
• tworzenia mini‑algorytmów bez VBA,
• upraszczania rozbudowanych obliczeń w jednej formule.

Funkcja REDUCE bardzo dobrze współpracuje z wieloma funkcjami jak JEŻELI, LET, PODZIEL.TEKST, ZŁĄCZ.TEKSTY, MAX, MIN, MAP i oczywiście z LAMBDA i wiele innych.

Jeżeli pracujesz na Excelu dla Microsoft 365, REDUCE jest jedną z tych funkcji, które pokazują, jak bardzo Excel odszedł od prostego modelu „jedna komórka = jedno obliczenie”.

Składnia i argumenty funkcji

Składnia

=REDUCE([wartość_początkowa];tablica;LAMBDA(akumulator;wartość;obliczenie))

Argumenty funkcji

• wartość_początkowa (opcjonalny)
  • ustawia punkt startowy dla całego procesu
  • może to być liczba, tekst, wartość logiczna albo pusty tekst
  • przykład: 0, 1, „”
• tablica (wymagany)
  • zakres lub tablica danych, które mają zostać przetworzone
  • funkcja przechodzi po każdym elemencie po kolei
• LAMBDA(akumulator;wartość;obliczenie) (wymagany)
  • definiuje logikę działania w każdym kroku
  • akumulator przechowuje wynik z poprzedniego kroku
  • wartość oznacza bieżący element tablicy
  • obliczenie zwraca nowy wynik

Jak działa funkcja REDUCE?

REDUCE działa iteracyjnie:

1. pobiera wartość początkową,
2. bierze pierwszy element z tablicy,
3. wykonuje obliczenie z LAMBDA,
4. zapisuje nowy wynik jako akumulator,
5. przechodzi do kolejnego elementu,
6. po zakończeniu zwraca jeden wynik końcowy.

Najważniejsze: REDUCE nie pokazuje wyników pośrednich. Zwraca tylko rezultat końcowy.

Przykłady użycia funkcji REDUCE

Jak obliczyć sumę wszystkich wartości za pomocą REDUCE?

Formuła

 =REDUCE(0;A4:A12;LAMBDA(suma;wartość;suma+wartość))

Krok po kroku

• REDUCE zaczyna od argumentu wartość_początkowa = 0.
• tablica = A4:A12 dostarcza kolejne liczby.
• LAMBDA(suma;wartość;…) oznacza:
  • suma → wynik z poprzedniego kroku,
  • wartość → bieżąca komórka.
• W pierwszym kroku Excel liczy 0 + A4.
• W kolejnym kroku liczy wynik_poprzedni + A5.
• Wyrażenie suma+wartość wykonuje się aż do końca zakresu.
• REDUCE zwraca tylko jeden wynik końcowy, czyli sumę całego zakresu.

Jak zsumować tylko wartości dodatnie?

Formuła

=REDUCE(0;A4:A8;LAMBDA(suma;wartość;JEŻELI(wartość>0;suma+wartość;suma)))

Krok po kroku

• wartość_początkowa = 0 ustawia początek sumowania.
• tablica = A42:A8 dostarcza kolejne liczby dodatnie i ujemne.
• LAMBDA(suma;wartość;…) steruje logiką warunkową.
• Część JEŻELI(wartość>0;…;…) sprawdza, czy bieżąca liczba jest dodatnia.
• Jeśli warunek jest spełniony, Excel liczy suma+wartość.
• Jeśli warunek nie jest spełniony, Excel zostawia samo suma.
• Dzięki temu wartości ujemne i zera nie zmieniają wyniku.
• REDUCE zwraca końcową sumę tylko dodatnich elementów.

Jak policzyć liczbę komórek spełniających warunek?

Formuła

=REDUCE(0;A4:A10;LAMBDA(licznik;wartość;JEŻELI(wartość>=100;licznik+1;licznik)))

Krok po kroku

• wartość_początkowa = 0 oznacza, że licznik startuje od zera.
• tablica = A4:A10 dostarcza kolejne wartości do sprawdzenia.
• LAMBDA(licznik;wartość;…) oznacza:
  • licznik → dotychczasowa liczba,
  • wartość → bieżąca komórka.
• JEŻELI(wartość>=100;licznik+1;licznik) zwiększa licznik tylko wtedy, gdy wartość spełnia warunek.
• Jeśli warunek nie jest spełniony, licznik pozostaje bez zmian.
• REDUCE przechodzi przez cały zakres.
• Wynik końcowy to liczba komórek o wartości co najmniej 100.

Jak zamienić całe zdanie na zapis jak w zdaniu, z wielką literą na początku i kropką na końcu?

Formuła

=LET(
tekst;A4;
wyrazy;PODZIEL.TEKST(tekst;" ");
REDUCE("";wyrazy;LAMBDA(wynik;wyraz;JEŻELI(wynik="";LITERY.WIELKIE(LEWY(wyraz;1))&LITERY.MAŁE(FRAGMENT.TEKSTU(wyraz;2;99));wynik&" "&LITERY.MAŁE(wyraz))))&".")

Zadanie z gwiazdką 😊

Krok po kroku

• LET porządkuje formułę i nadaje nazwy poszczególnym elementom.
• tekst;A2 pobiera całe zdanie z jednej komórki.
• wyrazy;PODZIEL.TEKST(tekst;” „) rozbija zdanie na pojedyncze słowa.
• REDUCE(„”;wyrazy;…) zaczyna budowę nowego tekstu od pustego ciągu.
• LAMBDA(wynik;wyraz;…) oznacza:
  • wynik → dotychczas zbudowane zdanie,
  • wyraz → bieżące słowo.
• JEŻELI(wynik=””;…;…) rozróżnia pierwszy wyraz od pozostałych.
• Dla pierwszego słowa formuła wykonuje:
  • LITERY.WIELKIE(LEWY(wyraz;1)) → zamienia pierwszą literę na wielką,
  • LITERY.MAŁE(FRAGMENT.TEKSTU(wyraz;2;99)) → resztę zamienia na małe litery.
• Dla kolejnych słów formuła dokleja spację i używa LITERY.MAŁE(wyraz).
• Na końcu &”.” dodaje kropkę.
• Wynik końcowy to zdanie zapisane jak klasyczne zdanie: pierwszy wyraz zaczyna się wielką literą, pozostałe są małymi literami, a na końcu pojawia się kropka.

Podsumowanie

REDUCE to funkcja, która bierze wiele elementów i zamienia je w jeden wynik końcowy. Właśnie dlatego świetnie nadaje się do sumowania, mnożenia, zliczania, filtrowania logiki oraz budowania jednego tekstu z wielu części.

Największa siła REDUCE polega na tym, że pozwala samodzielnie zdefiniować sposób agregacji danych. Nie jesteś ograniczony do gotowych funkcji typu SUMA czy ILOCZYN. Możesz zbudować własną regułę działania i zamknąć ją w jednej formule.

REDUCE bardzo dobrze współpracuje z LAMBDA, JEŻELI, LET, PODZIEL.TEKST, LEWY, FRAGMENT.TEKSTU i funkcjami zmiany wielkości liter. To właśnie w takich połączeniach pokazuje pełnię możliwości.

Funkcja działa wyłącznie w Excelu dla Microsoft 365. Nie znajdziesz jej w wersjach Excela do 2021. Jeżeli więc ktoś otworzy taki arkusz w starszej wersji, REDUCE nie będzie dostępna. Excel bywa wyrozumiały, ale nie aż tak.

W praktyce warto używać REDUCE wtedy, gdy chcesz przejść po tablicy danych i otrzymać jedną końcową odpowiedź. Jeżeli zależy Ci na wszystkich etapach pośrednich, wtedy lepszym wyborem będzie SCAN. Jeżeli chcesz tylko wynik końcowy, REDUCE jest dokładnie na swoim miejscu.

Zobacz również:

Szkolenia: